// Water caustics code in this file only is licensed under:
// CC BY-NC-SA 3.0 (Creative Commons Attribution-NonCommercial-ShareAlike 3.0 Unported)
// https://creativecommons.org/licenses/by-nc-sa/3.0/
//
// Adapted from: https://www.shadertoy.com/view/ssfBDf
// Modifications: top-down Minecraft XZ mapping, fixed visual settings, and
// integration with Sundial Lite's shadow and per-pixel lighting passes.

vec3 causticMod289(vec3 x) {
    return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 causticMod289(vec4 x) {
    return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 causticPermute(vec4 x) {
    return causticMod289(((x * 34.0) + 10.0) * x);
}

vec4 causticTaylorInvSqrt(vec4 r) {
    return 1.79284291400159 - 0.85373472095314 * r;
}

vec4 causticSimplexDerivative(vec3 v) {
    const vec2 C = vec2(1.0 / 6.0, 1.0 / 3.0);
    const vec4 D = vec4(0.0, 0.5, 1.0, 2.0);

    vec3 i = floor(v + dot(v, C.yyy));
    vec3 x0 = v - i + dot(i, C.xxx);
    vec3 g = step(x0.yzx, x0.xyz);
    vec3 l = 1.0 - g;
    vec3 i1 = min(g.xyz, l.zxy);
    vec3 i2 = max(g.xyz, l.zxy);
    vec3 x1 = x0 - i1 + C.xxx;
    vec3 x2 = x0 - i2 + C.yyy;
    vec3 x3 = x0 - D.yyy;

    i = causticMod289(i);
    vec4 p = causticPermute(causticPermute(causticPermute(
        i.z + vec4(0.0, i1.z, i2.z, 1.0))
        + i.y + vec4(0.0, i1.y, i2.y, 1.0))
        + i.x + vec4(0.0, i1.x, i2.x, 1.0));

    float n_ = 1.0 / 7.0;
    vec3 ns = n_ * D.wyz - D.xzx;
    vec4 j = p - 49.0 * floor(p * ns.z * ns.z);
    vec4 x_ = floor(j * ns.z);
    vec4 y_ = floor(j - 7.0 * x_);
    vec4 x = x_ * ns.x + ns.yyyy;
    vec4 y = y_ * ns.x + ns.yyyy;
    vec4 h = 1.0 - abs(x) - abs(y);
    vec4 b0 = vec4(x.xy, y.xy);
    vec4 b1 = vec4(x.zw, y.zw);
    vec4 s0 = floor(b0) * 2.0 + 1.0;
    vec4 s1 = floor(b1) * 2.0 + 1.0;
    vec4 sh = -step(h, vec4(0.0));
    vec4 a0 = b0.xzyw + s0.xzyw * sh.xxyy;
    vec4 a1 = b1.xzyw + s1.xzyw * sh.zzww;

    vec3 p0 = vec3(a0.xy, h.x);
    vec3 p1 = vec3(a0.zw, h.y);
    vec3 p2 = vec3(a1.xy, h.z);
    vec3 p3 = vec3(a1.zw, h.w);
    vec4 norm = causticTaylorInvSqrt(vec4(dot(p0, p0), dot(p1, p1), dot(p2, p2), dot(p3, p3)));
    p0 *= norm.x;
    p1 *= norm.y;
    p2 *= norm.z;
    p3 *= norm.w;

    vec4 m = max(0.6 - vec4(dot(x0, x0), dot(x1, x1), dot(x2, x2), dot(x3, x3)), 0.0);
    vec4 m2 = m * m;
    vec4 m3 = m2 * m;
    vec4 m4 = m2 * m2;
    vec4 px = vec4(dot(p0, x0), dot(p1, x1), dot(p2, x2), dot(p3, x3));

    vec3 derivative = m4.x * p0 + m4.y * p1 + m4.z * p2 + m4.w * p3;
    derivative -= 8.0 * (
        m3.x * px.x * x0
        + m3.y * px.y * x1
        + m3.z * px.z * x2
        + m3.w * px.w * x3
    );
    float value = dot(m4, px);
    return vec4(derivative * 42.0, value * 42.0);
}

float causticDomainWarp(vec3 pos) {
    const float coordinateWarp = 0.050;

    vec4 n = causticSimplexDerivative(pos);
    pos -= coordinateWarp * n.xyz;
    pos *= 1.62;
    n = causticSimplexDerivative(pos);
    pos -= coordinateWarp * n.xyz;
    n = causticSimplexDerivative(pos);
    pos -= coordinateWarp * n.xyz;
    n = causticSimplexDerivative(pos);
    return n.w;
}

float waterCaustic(vec3 mcPos) {
    float causticStrength = 0.5;

    #ifdef WATER_CAUSTIC
        const float patternScale = 1.33333333;
        const float contrast = 4.6;

        // XZ is used directly: this is a top-down floor pattern with no stretch
        // or perspective projection from a side-view plane.
        float causticTime = frameTimeCounter * WATER_WAVE_SPEED;
        vec3 position = vec3(mcPos.x * patternScale, causticTime, mcPos.z * patternScale);
        float noiseValue = mix(causticDomainWarp(position), causticDomainWarp(position + 1.0), 0.5);
        float intensity = exp(clamp(noiseValue * contrast - 1.0, -5.0, 2.4));
        float light = intensity / (0.55 + intensity);
        light = pow(clamp(light, 0.0, 1.0), 1.18);
        causticStrength = mix(0.1, 1.0, light);
    #endif

    return causticStrength;
}
