// Ars Noveau

import crafttweaker.api.item.IItemStack;


// Normal Crafting
// ---------------------------------------------------------------------------------------------------------------------------------------------

// The Potentia Sapling, can be used to make Archwood Saplings in a pinch.
craftingTable.addShapeless("potentia_sapling", <item:contenttweaker:potentia_sapling>, [<item:ars_nouveau:magic_clay>, <tag:items:minecraft:saplings>]);

// The Spellbook Recipe Changes
craftingTable.removeByName("ars_nouveau:novice_spell_book");
craftingTable.addShapeless("new_novice_spell_book", <item:ars_nouveau:novice_spell_book>, 
[<item:minecraft:book>, <item:twilightforest:ironwood_shovel>, <item:twilightforest:ironwood_pickaxe>, <item:twilightforest:ironwood_axe>, <item:twilightforest:ironwood_sword>, <item:twilightforest:naga_scale>]);

craftingTable.removeByName("ars_nouveau:apprentice_spell_book_upgrade");
craftingTable.addShapeless("new_apprentice_spell_book", <item:ars_nouveau:apprentice_spell_book>, [<item:ars_nouveau:novice_spell_book>, <item:twilightforest:knightmetal_ingot>, <item:minecraft:blaze_rod>, <tag:items:forge:gems>], (usualOut as IItemStack, inputs as IItemStack[]) => {
   return usualOut.withTag(inputs[0].tag);
});

craftingTable.removeByName("ars_nouveau:archmage_spell_book_upgrade");
craftingTable.addShapeless("new_archmage_spell_book", <item:ars_nouveau:archmage_spell_book>, [<item:ars_nouveau:apprentice_spell_book>, <item:minecraft:shulker_shell>, <item:ars_nouveau:wilden_tribute>, <item:minecraft:nether_star>], (usualOut as IItemStack, inputs as IItemStack[]) => {
   return usualOut.withTag(inputs[0].tag);
});

// Source Berry.
craftingTable.addShapeless("source_berry", <item:ars_nouveau:mana_berry>, [<item:ars_nouveau:mana_gem>, <item:minecraft:sweet_berries> | <item:rootsclassic:elderberry> | <item:druidcraft:blueberries> | <item:druidcraft:elderberries> | <item:rootsclassic:blackcurrant> | <item:rootsclassic:redcurrant> | <item:rootsclassic:whitecurrant> | <item:rootsclassic:nightshade>]);

// ---------------------------------------------------------------------------------------------------------------------------------------------


// Enchanting Apparatus
// ---------------------------------------------------------------------------------------------------------------------------------------------
// The Matrix Enchanting Table
<recipetype:ars_nouveau:enchanting_apparatus>.addRecipe("matrix_enchanter", <item:quark:matrix_enchanter>, <item:minecraft:enchanting_table>, 
[<item:ars_nouveau:mana_gem>, <item:ars_nouveau:mana_gem>, <item:ars_nouveau:mana_gem>, <item:ars_nouveau:mana_gem>, 
<item:minecraft:bookshelf>, <item:minecraft:bookshelf>, <item:minecraft:bookshelf>, <item:minecraft:bookshelf>]);


// The Totem of Undying
<recipetype:ars_nouveau:enchanting_apparatus>.addRecipe("totem_of_undying", <item:minecraft:totem_of_undying>, <item:minecraft:emerald>, 
[<item:minecraft:gold_ingot>, <item:minecraft:gold_ingot>, <item:minecraft:gold_ingot>, <item:minecraft:gold_ingot>, 
<item:twilightforest:liveroot>, <item:twilightforest:liveroot>, <item:twilightforest:liveroot>, <item:twilightforest:liveroot>]);


// The Entangled Block
craftingTable.removeByName("entangled:block");
<recipetype:ars_nouveau:enchanting_apparatus>.addRecipe("entangled_block", <item:entangled:block>, <item:minecraft:ender_chest>, 
[<item:minecraft:purpur_block>, <item:minecraft:purpur_block>, <item:minecraft:purpur_block>, <item:minecraft:purpur_block>, 
<item:minecraft:nether_bricks>, <item:minecraft:nether_bricks>, <item:minecraft:nether_bricks>, <item:minecraft:nether_bricks>]);


// The Entangled Binder
craftingTable.removeRecipe(<item:entangled:item>);
<recipetype:ars_nouveau:enchanting_apparatus>.addRecipe("entangled_binder", <item:entangled:item>, <item:minecraft:stick>, 
[<item:minecraft:iron_ingot>, <item:minecraft:iron_ingot>, <item:minecraft:emerald>, <item:minecraft:emerald>]);

// ---------------------------------------------------------------------------------------------------------------------------------------------


// <item:minecraft:air>













