// Blood Magic

import crafttweaker.api.item.IItemStack;

// I accidentally added some of the recipes to the datapack, check it if you're wondering where my other changes are.

// Blood Altar
// ---------------------------------------------------------------------------------------------------------------------------------------------
// Making the Wither Skeleton Totem crafted via blood magic to add more use to the mod.
craftingTable.removeRecipe(<item:totemmod:totem_base>);
<recipetype:bloodmagic:altar>.addRecipe("basalt_pedestal", <item:totemmod:totem_base>, <item:minecraft:polished_basalt>, 2, 25000, 20, 20);
craftingTable.removeRecipe(<item:totemmod:totem_top>);
<recipetype:bloodmagic:altar>.addRecipe("wrath_totem", <item:totemmod:totem_top>, <item:minecraft:wither_skeleton_skull>, 2, 25000, 20, 20);

// You need Fiery Metal to make the Tier 3 Blood Orb. This is so progression is slightly locked behind bosses.
// This got moved to a datapack.

// Experiment 115, a very fitting food for a blood mage. You can also make Hydra Chops with a strong enough altar.
<recipetype:bloodmagic:altar>.addRecipe("experiment_115", <item:twilightforest:experiment_115>, <item:eidolon:tallow>, 1, 1000, 5, 5);
<recipetype:bloodmagic:altar>.addRecipe("hydra_chop", <item:twilightforest:hydra_chop>, <item:minecraft:cooked_porkchop>, 3, 1000, 5, 5);

// Turtle Eggs. Botanists don't have dominion over *all* life, y'know.
<recipetype:bloodmagic:altar>.addRecipe("turtle_egg", <item:minecraft:turtle_egg>, <item:minecraft:heart_of_the_sea>, 2, 4000, 10, 10);

// Sponge
<recipetype:bloodmagic:altar>.addRecipe("sponge", <item:minecraft:sponge>, <item:quark:yellow_quilted_wool>, 2, 4000, 10, 10);

// Metaphoric Flesh makes Tier 2 Slates Cheaper.
<recipetype:bloodmagic:altar>.addRecipe("flesh_to_slates", <item:bloodmagic:reinforcedslate>, <item:astral:metaphoric_flesh>, 1, 1000, 10, 10);

// Blood Thorn. Endgame Signifier of a Tier V Altar.
<recipetype:bloodmagic:altar>.addRecipe("blood_thorn", <item:contenttweaker:blood_thorn>, <item:twilightforest:thorn_rose>, 4, 100000, 10, 10);


// ---------------------------------------------------------------------------------------------------------------------------------------------


// Alchemy Table
// ---------------------------------------------------------------------------------------------------------------------------------------------
/*
craftingTable.removeRecipe(<item:metalbushesmod:blaze_bush>);
<recipetype:bloodmagic:alchemytable>.addRecipe("bloody_blaze_bush", <item:metalbushesmod:blaze_bush>, 
[<item:metalbushesmod:bush_base>, <item:minecraft:dead_bush>, <item:twilightforest:fiery_blood>, 
<item:twilightforest:fiery_tears>, <item:druidcraft:fiery_glass_block>, <item:botania:blaze_block>], 10000, 100, 2);
*/
// ---------------------------------------------------------------------------------------------------------------------------------------------


// Hellfire Forge
// ---------------------------------------------------------------------------------------------------------------------------------------------
craftingTable.removeRecipe(<item:metalbushesmod:nether_quartz_bush>);
<recipetype:bloodmagic:soulforge>.addRecipe("bloody_quartz_bush", <item:metalbushesmod:nether_quartz_bush>, 
[<item:metalbushesmod:bush_base>, <item:bloodmagic:plantoil>, <item:minecraft:nether_quartz_ore>, <item:minecraft:quartz_block>], 1000, 250);
// ---------------------------------------------------------------------------------------------------------------------------------------------


// Crafting
// ---------------------------------------------------------------------------------------------------------------------------------------------
// Obsidian Path! This stuff is really good and was likely supposed to be left for tier 5, but I'm adding this holdover recipe for endgame.

craftingTable.addShapeless("obsidian_path", <item:bloodmagic:obsidianbrickpath>, [<item:minecraft:obsidian>, <item:quark:biotite>, <item:bloodmagic:wornstonebrickpath>]);

craftingTable.addShaped("tiled_obsidian_path", <item:bloodmagic:obsidiantilepath> * 4, [
    [<item:bloodmagic:obsidianbrickpath>, <item:bloodmagic:obsidianbrickpath>],
    [<item:bloodmagic:obsidianbrickpath>, <item:bloodmagic:obsidianbrickpath>]]);
// ---------------------------------------------------------------------------------------------------------------------------------------------






