/*Set up Imports */
import crafttweaker.api.item.IItemStack;

/* Set Values and Variables */
val air = <item:minecraft:air>;
var RArray = [
	<item:snad__reforged:snad>,
	<item:snad__reforged:red_snad>,
	<item:snad__reforged:soul_snad>,
	<item:minecraft:shears>,
	<item:doomangelring:itemdoomangelring>,
	<item:create:encased_chain_drive>
];

/* Remove recipes */
for item in RArray {
    craftingTable.removeRecipe(item);
}

/* Re-Add Recipes */
/* Add recipes that were in quark */
craftingTable.addShaped("thb_sticks_from_logs", <item:minecraft:stick> * 16, [
    [<tag:items:minecraft:logs>],
    [<tag:items:minecraft:logs>],
]);
craftingTable.addShaped("thb_chest_from_logs", <item:minecraft:chest> *4, [
	[<tag:items:minecraft:logs>, <tag:items:minecraft:logs>, <tag:items:minecraft:logs>],
	[<tag:items:minecraft:logs>, air, <tag:items:minecraft:logs>],
	[<tag:items:minecraft:logs>, <tag:items:minecraft:logs>, <tag:items:minecraft:logs>]
]);
craftingTable.addShaped("thb_hopper_from_logs", <item:minecraft:hopper>, [
	[<item:minecraft:iron_ingot>, <tag:items:minecraft:logs>, <item:minecraft:iron_ingot>],
	[<item:minecraft:iron_ingot>, <tag:items:minecraft:logs>, <item:minecraft:iron_ingot>],
	[<item:minecraft:air>, <item:minecraft:iron_ingot>, <item:minecraft:air>]
]);

/* Fix snad and soul snad recipe to something more difficult. */
craftingTable.addShaped("thb_harder_snad", <item:snad__reforged:snad> * 4, [
	[<item:minecraft:bone_meal>, <item:minecraft:sand>, <item:minecraft:bone_meal>], 
	[<item:minecraft:sand>, <item:minecraft:sugar>, <item:minecraft:sand>], 
	[<item:minecraft:bone_meal>, <item:minecraft:sand>, <item:minecraft:bone_meal>]
]);
craftingTable.addShaped("thb_harder_red_snad", <item:snad__reforged:red_snad> * 4, [
	[<item:minecraft:bone_meal>, <item:minecraft:red_sand>, <item:minecraft:bone_meal>], 
	[<item:minecraft:red_sand>, <item:minecraft:sugar>, <item:minecraft:red_sand>], 
	[<item:minecraft:bone_meal>, <item:minecraft:red_sand>, <item:minecraft:bone_meal>]
]);
craftingTable.addShaped("thb_harder_soul_snad", <item:snad__reforged:soul_snad> * 4, [
	[<item:minecraft:bone_meal>, <item:minecraft:soul_sand>, <item:minecraft:bone_meal>], 
	[<item:minecraft:soul_sand>, <item:minecraft:sugar>, <item:minecraft:soul_sand>], 
	[<item:minecraft:bone_meal>, <item:minecraft:soul_sand>, <item:minecraft:bone_meal>]
]);

/* Add recipe for nametag */
craftingTable.addShapeless("thb_nametag_recipe", <item:minecraft:name_tag>,
	[<item:minecraft:string>, <item:minecraft:paper>]
);

/* Re-add shear recipe to fix it */
craftingTable.addShapedMirrored("thb_shear_fix", <item:minecraft:shears>, [
	[<item:minecraft:air>, <item:minecraft:iron_ingot>],
	[<item:minecraft:iron_ingot>, <item:minecraft:air>]
]);

/* Change Recipe for angel ring to something slightly harder */
craftingTable.addShaped("thb_harder_angel_ring", <item:doomangelring:itemdoomangelring>, [
	[<item:minecraft:feather>, <item:minecraft:netherite_ingot>, <item:minecraft:feather>],
	[<item:minecraft:netherite_ingot>, <item:minecraft:elytra>, <item:minecraft:netherite_ingot>],
	[<item:minecraft:nether_star>, <item:minecraft:netherite_ingot>, <item:minecraft:nether_star>]
]);

/* Add recipe for clay block to clay ball */
craftingTable.addShapeless("thb_clayblock_to_ball", <item:minecraft:clay_ball> * 4, 
	[<item:minecraft:clay>]
);

/* Add in recipe for slime pearls to make them slightly less sucky to get */
craftingTable.addShaped("thb_slimepearl_from_essence", <item:xreliquary:slime_pearl> * 4, [
	[<item:mysticalagriculture:slime_essence>, <item:mysticalagriculture:slime_essence>, <item:mysticalagriculture:slime_essence>],
	[<item:mysticalagriculture:slime_essence>, <tag:items:forge:ender_pearls>, <item:mysticalagriculture:slime_essence>],
	[<item:mysticalagriculture:slime_essence>, <item:mysticalagriculture:slime_essence>, <item:mysticalagriculture:slime_essence>]
]);

/* Add in reversal recipe for tiny coal and charcoal */
craftingTable.addShaped("thb_coal_from_tiny", <item:minecraft:coal>, [
	[<item:tinycoal:tinycoal>, <item:tinycoal:tinycoal>, <item:tinycoal:tinycoal>],
	[<item:tinycoal:tinycoal>, air, <item:tinycoal:tinycoal>],
	[<item:tinycoal:tinycoal>, <item:tinycoal:tinycoal>, <item:tinycoal:tinycoal>]
]);
craftingTable.addShaped("thb_charcol_from_tiny", <item:minecraft:charcoal>, [
	[<item:tinycoal:tinycharcoal>, <item:tinycoal:tinycharcoal>, <item:tinycoal:tinycharcoal>],
	[<item:tinycoal:tinycharcoal>, air, <item:tinycoal:tinycharcoal>],
	[<item:tinycoal:tinycharcoal>, <item:tinycoal:tinycharcoal>, <item:tinycoal:tinycharcoal>]
]);