import mods.jei.JEI.removeAndHide as rah;
#modloaded immersiveengineering

# Remove Ores from JEI
rah(<immersiveengineering:ore>);
rah(<immersiveengineering:ore:1>);
rah(<immersiveengineering:ore:2>);
rah(<immersiveengineering:ore:3>);
rah(<immersiveengineering:ore:4>);
rah(<immersiveengineering:ore:5>);

# HOP Graphite Dust
mods.thermalexpansion.Compactor.addPressRecipe(<immersiveengineering:material:18>, <immersiveengineering:material:17> * 8, 15000);

# Coke Dust
for coke in oreDict.fuelCoke.items {
    mods.thermalexpansion.Pulverizer.addRecipe(<immersiveengineering:material:17>, coke, 4000);
    mods.enderio.SagMill.addRecipe([<immersiveengineering:material:17>], [1.0f], coke, "NONE", 4000);
}

for cokeBlock in oreDict.blockFuelCoke.items {
    mods.thermalexpansion.Pulverizer.addRecipe(<immersiveengineering:material:17> * 9, cokeBlock, 15000);
    mods.enderio.SagMill.addRecipe([<immersiveengineering:material:17> * 9], [1.0f], cokeBlock, "NONE", 15000);
}

# EnderIO Examples
/*
    SAG Mill
    bonusType is an enum from RecipeBonusType: NONE, MULTIPLY_OUTPUT, CHANCE_ONLY
    mods.enderio.SagMill.addRecipe(outputs[], chances[], input, bonusType, fuel);
 */

# Thermal Expansion Examples
# Induction Smelter
/*
for steelIngot in oreDict.ingotSteel.items {
    mods.thermalexpansion.InductionSmelter.addRecipe(<extendedcrafting:material>, steelIngot, <minecraft:coal> * 3, 15000);
    mods.thermalexpansion.InductionSmelter.addRecipe(<extendedcrafting:material> * 3, steelIngot * 3, <minecraft:coal_block>, 15000);
}
 */