import mods.jei.JEI.removeAndHide as rah;
#modloaded environmentaltech

###################### 
#      Modifiers     #
######################

# Resistance Modifier harder recipe
recipes.remove(<environmentaltech:modifier_resistance>);

mods.extendedcrafting.TableCrafting.addShapedMirrored(0, <environmentaltech:modifier_resistance>, 
[
    [<ore:blockPladium>, <mysticalagriculture:charm:6>, <ore:blockPladium>],
    [<environmentaltech:mica>, <environmentaltech:modifier_null>, <environmentaltech:mica>], 
    [<mysticalagriculture:witherproof_block>, <ore:crystalLonsdaleite>, <mysticalagriculture:witherproof_block>]
]);

###################### 
#    Nano Beacon     #
######################

# Tier 5
recipes.remove(<environmentaltech:nano_cont_personal_5>);

mods.extendedcrafting.TableCrafting.addShaped(<environmentaltech:nano_cont_personal_5>, 
[
    [<ore:blockCrystaltine>, <draconicevolution:draconium_block:1>, <ore:blockCrystaltine>],
    [<ore:blockIonite>, <environmentaltech:nano_cont_personal_4>, <ore:blockIonite>], 
    [<environmentaltech:mica>, <environmentaltech:modifier_null>, <environmentaltech:mica>]
]);

# Tier 6
recipes.remove(<environmentaltech:nano_cont_personal_6>);

mods.extendedcrafting.TableCrafting.addShaped(<environmentaltech:nano_cont_personal_6>, 
[
    [<ore:blockCosmicNeutronium>, <ore:blockDraconiumAwakened>, <ore:blockCosmicNeutronium>],
    [<ore:blockAethium>, <environmentaltech:nano_cont_personal_5>, <ore:blockAethium>], 
    [<environmentaltech:mica>, <environmentaltech:modifier_null>, <environmentaltech:mica>]
]);


###################### 
#     Void Miner     #
######################

# Tier 1
recipes.remove(<environmentaltech:void_ore_miner_cont_1>);

recipes.addShaped(<environmentaltech:void_ore_miner_cont_1>, [
    [<ore:blockLitherite>, <ore:blockMithril>, <ore:blockLitherite>], 
    [<ore:blockLitherite>, <environmentaltech:diode>, <ore:blockLitherite>], 
    [<environmentaltech:interconnect>, <ore:etLaserLens>, <environmentaltech:interconnect>]
]);

# Tier 5
recipes.remove(<environmentaltech:void_ore_miner_cont_5>);

mods.extendedcrafting.TableCrafting.addShaped(0, <environmentaltech:void_ore_miner_cont_5>, [
    [<ore:blockIonite>, <environmentaltech:void_ore_miner_cont_4>, <ore:blockIonite>], 
    [<ore:blockIonite>, <industrialforegoing:laser_drill>, <ore:blockIonite>], 
    [<ore:blockIonite>, <mekanism:machineblock2:15>, <ore:blockIonite>]
]);

# Tier 6
recipes.remove(<environmentaltech:void_ore_miner_cont_6>);

mods.extendedcrafting.TableCrafting.addShaped(0, <environmentaltech:void_ore_miner_cont_6>, [
    [<ore:blockAethium>, <environmentaltech:void_ore_miner_cont_5>, <ore:blockAethium>], 
    [<ore:blockCrystaltine>, <industrialforegoing:laser_drill>, <ore:blockCrystaltine>], 
    [<ore:blockAethium>, <mekanism:machineblock2:15>, <ore:blockAethium>]
]);

###################### 
#       Solar        #
######################

var t4cell = <environmentaltech:solar_cell_pladium>;
var t5cell = <environmentaltech:solar_cell_ionite>;
var t6cell = <environmentaltech:solar_cell_aethium>;

# Tier 4
recipes.remove(<environmentaltech:solar_cont_4>);

mods.extendedcrafting.TableCrafting.addShaped(0, <environmentaltech:solar_cont_4>, 
[
    [<mekanismgenerators:generator:5>, t4cell, <extendedcrafting:material:10>, t4cell, <mekanismgenerators:generator:5>], 
    [t4cell, <thermalexpansion:frame:130>, <ore:blockPladium>, <thermalexpansion:frame:130>, t4cell], 
    [<extendedcrafting:material:10>, <ore:blockPladium>, <environmentaltech:solar_cont_3>, <ore:blockPladium>, <extendedcrafting:material:10>], 
    [t4cell, <thermalexpansion:frame:130>, <ore:blockPladium>, <thermalexpansion:frame:130>, t4cell], 
    [<mekanismgenerators:generator:5>, t4cell, <extendedcrafting:material:10>, t4cell, <mekanismgenerators:generator:5>]
]);

# Tier 5
recipes.remove(<environmentaltech:solar_cont_5>);

mods.extendedcrafting.TableCrafting.addShaped(0, <environmentaltech:solar_cont_5>, 
[
    [<mekanismgenerators:generator:5>, t5cell, t5cell, <extendedcrafting:material:12>, t5cell, t5cell, <mekanismgenerators:generator:5>], 
    [t5cell, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <thermalexpansion:frame>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, t5cell], 
    [t5cell, <ore:itemEnhancedChassiParts>, <thermalexpansion:frame:131>, <ore:blockIonite>, <thermalexpansion:frame:131>, <ore:itemEnhancedChassiParts>, t5cell], 
    [<extendedcrafting:material:12>, <thermalexpansion:frame>, <ore:blockIonite>, <environmentaltech:solar_cont_4>, <ore:blockIonite>, <thermalexpansion:frame>, <extendedcrafting:material:12>], 
    [t5cell, <ore:itemEnhancedChassiParts>, <thermalexpansion:frame:131>, <ore:blockIonite>, <thermalexpansion:frame:131>, <ore:itemEnhancedChassiParts>, t5cell], 
    [t5cell, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <thermalexpansion:frame>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, t5cell], 
    [<mekanismgenerators:generator:5>, t5cell, t5cell, <extendedcrafting:material:12>, t5cell, t5cell, <mekanismgenerators:generator:5>]
]);

# Tier 6
recipes.remove(<environmentaltech:solar_cont_6>);

mods.extendedcrafting.TableCrafting.addShaped(0, <environmentaltech:solar_cont_6>, [
    [<mekanism:machineblock3:1>, t6cell, t6cell, t6cell, <extendedcrafting:material:12>, t6cell, t6cell, t6cell, <mekanism:machineblock3:1>], 
    [t6cell, <ore:ingotUltimate>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:ingotUltimate>, t6cell], 
    [t6cell, <ore:itemEnhancedChassiParts>, <draconicevolution:particle_generator:2>, <ore:blockAethium>, <draconicevolution:energy_pylon>, <ore:blockAethium>, <draconicevolution:particle_generator:2>, <ore:itemEnhancedChassiParts>, t6cell], 
    [t6cell, <ore:itemEnhancedChassiParts>, <ore:blockAethium>, <thermalexpansion:frame:132>, <draconicevolution:awakened_core>, <thermalexpansion:frame:132>, <ore:blockAethium>, <ore:itemEnhancedChassiParts>, t6cell], 
    [<extendedcrafting:material:12>, <ore:itemEnhancedChassiParts>, <draconicevolution:energy_pylon>, <draconicevolution:awakened_core>, <environmentaltech:solar_cont_5>, <draconicevolution:awakened_core>, <draconicevolution:energy_pylon>, <ore:itemEnhancedChassiParts>, <extendedcrafting:material:12>], 
    [t6cell, <ore:itemEnhancedChassiParts>, <ore:blockAethium>, <thermalexpansion:frame:132>, <draconicevolution:awakened_core>, <thermalexpansion:frame:132>, <ore:blockAethium>, <ore:itemEnhancedChassiParts>, t6cell], 
    [t6cell, <ore:itemEnhancedChassiParts>, <draconicevolution:particle_generator:2>, <ore:blockAethium>, <draconicevolution:energy_pylon>, <ore:blockAethium>, <draconicevolution:particle_generator:2>, <ore:itemEnhancedChassiParts>, t6cell], 
    [t6cell, <ore:ingotUltimate>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:itemEnhancedChassiParts>, <ore:ingotUltimate>, t6cell], 
    [<mekanism:machineblock3:1>, t6cell, t6cell, t6cell, <extendedcrafting:material:12>, t6cell, t6cell, t6cell, <mekanism:machineblock3:1>]
]);
###################### 
#       Blocks       #
######################

###################### 
#      Materials     #
######################

# Lonsdaleite
recipes.addShapedMirrored(<environmentaltech:lonsdaleite_crystal> * 3, 
[
    [<ore:gemQuartzBlack>, <ore:dustWither>, <ore:gemQuartzBlack>],
    [<ore:shardPrismarine>, <ore:ingotBlackIron>, <ore:shardPrismarine>], 
    [<ore:gemQuartzBlack>, <ore:dustWither>, <ore:gemQuartzBlack>]
]);

###################### 
#        Misc        #
######################