import mods.jei.JEI.removeAndHide as rah;
#modloaded quantumstorage

# Quantum Storage Disk
mods.extendedcrafting.CombinationCrafting.addRecipe(<quantumstorage:quantumstoragedisk>, 500000000, 250000, <quantumstorage:quantum_storage_unit>, 
[
<refinedstorage:storage_part>, <refinedstorage:storage_part:1>, <refinedstorage:storage_part:2>, <refinedstorage:storage_part:3>,
<rebornstorage:storagepart>, <rebornstorage:storagepart:1>, <rebornstorage:storagepart:2>, <rebornstorage:storagepart:3>,
<morerefinedstorage:storagepart>, <morerefinedstorage:storagepart:1>, <morerefinedstorage:storagepart:2>,
<minecraft:chest>, <ironchest:iron_chest>, <ironchest:iron_chest:1>, <ironchest:iron_chest:2>, <ironchest:iron_chest:3>, <ironchest:iron_chest:4>, <ironchest:iron_chest:5>, <ironchest:iron_chest:6>, <ironchest:iron_chest:7>,
<quantumstorage:chest_iron>, <quantumstorage:chest_gold>, <quantumstorage:chest_diamond>, <quantumstorage:chest_quantum>
]);

# Quantum Storage Unit
recipes.remove(<quantumstorage:quantum_storage_unit>);

recipes.addShaped("Quantum Storage Unit from Machine Frame", <quantumstorage:quantum_storage_unit>, [
    [<minecraft:obsidian>, <minecraft:obsidian>, <minecraft:obsidian>], 
    [<minecraft:ender_eye>, <quantumstorage:chest_quantum>, <minecraft:ender_eye>], 
    [<ore:ingotIron>, <thermalexpansion:frame>, <ore:ingotIron>]
]);
recipes.addShaped("Quantum Storage Unit from Machine Case", <quantumstorage:quantum_storage_unit>, [
    [<minecraft:obsidian>, <minecraft:obsidian>, <minecraft:obsidian>], 
    [<minecraft:ender_eye>, <quantumstorage:chest_quantum>, <minecraft:ender_eye>], 
    [<ore:ingotIron>, <teslacorelib:machine_case>, <ore:ingotIron>]
]);

# Quantum Tank
recipes.remove(<quantumstorage:quantum_tank>);

recipes.addShaped("Quantum Tank from Machine Frame", <quantumstorage:quantum_tank>, [
    [<minecraft:obsidian>, <minecraft:obsidian>, <minecraft:obsidian>], 
    [<minecraft:ender_eye>, <mekanism:machineblock2:11>.withTag({tier:3}), <minecraft:ender_eye>], 
    [<extrautils2:drum:3>, <thermalexpansion:frame>, <extrautils2:drum:3>]
]);
recipes.addShaped("Quantum Tank from Machine Case", <quantumstorage:quantum_tank>, [
    [<minecraft:obsidian>, <minecraft:obsidian>, <minecraft:obsidian>], 
    [<minecraft:ender_eye>, <mekanism:machineblock2:11>.withTag({tier:3}), <minecraft:ender_eye>], 
    [<extrautils2:drum:3>, <teslacorelib:machine_case>, <extrautils2:drum:3>]
]);

# Quantum Crafter
recipes.remove(<quantumstorage:quantumcrafter>);

mods.extendedcrafting.TableCrafting.addShaped(0, <quantumstorage:quantumcrafter>, [
    [<ore:dustMana>, <extendedcrafting:material>, <ore:dustMana>], 
    [<extendedcrafting:material>, <quantumstorage:quantum_storage_unit>, <extendedcrafting:material>], 
    [<ore:dustMana>, <extendedcrafting:material>, <ore:dustMana>]
]);

# Quantum Battery
rah(<quantumstorage:quantum_battery>);
rah(<quantumstorage:quantumstoragediskfluid>);