//Earthworks and Better With Mods recipe compatibility script


//remove current recipes for dirt pile/ball
recipes.removeShapeless(<minecraft:dirt>, [<betterwithmods:dirt_pile>, <betterwithmods:dirt_pile>, <betterwithmods:dirt_pile>, <betterwithmods:dirt_pile>]);
recipes.removeShapeless(<betterwithmods:dirt_slab>, [<betterwithmods:dirt_pile>, <betterwithmods:dirt_pile>]);
recipes.removeShaped(<minecraft:dirt>, 
[[<earthworks:item_dirt>, <earthworks:item_dirt>],
[<earthworks:item_dirt>, <earthworks:item_dirt>]]);
recipes.removeShaped(<earthworks:item_mud>,
[[<earthworks:item_dirt>, <earthworks:item_dirt>, <earthworks:item_dirt>],
[<earthworks:item_dirt>, <minecraft:water_bucket>, <earthworks:item_dirt>],
[<earthworks:item_dirt>, <earthworks:item_dirt>, <earthworks:item_dirt>]]);

//add item_dirt and dirt_ball to the same ore dict
val dustDirt = <ore:dustDirt>;
dustDirt.add(<betterwithmods:dirt_pile>);
dustDirt.add(<earthworks:item_dirt>);

//re instate removed recipes as dustDirt
recipes.addShaped(<minecraft:dirt>,
[[<ore:dustDirt>, <ore:dustDirt>],
[<ore:dustDirt>, <ore:dustDirt>]]);
recipes.addShaped(<earthworks:item_mud> * 8,
[[<ore:dustDirt>, <ore:dustDirt>, <ore:dustDirt>],
[<ore:dustDirt>, <minecraft:water_bucket>, <ore:dustDirt>],
[<ore:dustDirt>, <ore:dustDirt>, <ore:dustDirt>]]);

//remove current recipes for sand pile/ball
recipes.removeShapeless(<minecraft:sand>, [<betterwithmods:sand_pile>, <betterwithmods:sand_pile>, <betterwithmods:sand_pile>, <betterwithmods:sand_pile>]);
recipes.removeShapeless(<earthworks:item_adobe>);
recipes.removeShapeless(<earthworks:item_lime_plaster>);
recipes.removeShaped(<minecraft:sand>,
[[<earthworks:item_sand>, <earthworks:item_sand>],
[<earthworks:item_sand>, <earthworks:item_sand>]]);

//add item_sand and sand_pile to the same ore dict
val dustSand = <ore:dustSand>;
dustSand.add(<betterwithmods:sand_pile>);
dustSand.add(<earthworks:item_sand>);

//re instate removed recipes as dustSand
recipes.addShaped(<minecraft:sand>,
[[<ore:dustSand>, <ore:dustSand>],
[<ore:dustSand>, <ore:dustSand>]]);
recipes.addShapeless(<earthworks:item_adobe> * 8, [<minecraft:clay_ball>, <minecraft:clay_ball>, <minecraft:clay_ball>, <minecraft:clay_ball>, <minecraft:wheat>, <minecraft:clay_ball>, <minecraft:clay_ball>, <ore:dustSand>, <ore:dustSand>]);
recipes.addShapeless(<earthworks:item_lime_plaster> * 8, [<earthworks:item_quicklime>, <earthworks:item_quicklime>, <earthworks:item_quicklime>, <earthworks:item_quicklime>, <minecraft:water_bucket>, <ore:dustSand>, <ore:dustSand>, <ore:dustSand>, <ore:dustSand>]);
recipes.addShapeless(<earthworks:item_lime_plaster> * 2, [<earthworks:item_slaked_lime>, <ore:dustSand>]);
